Add a binary_heap module

binary_heap.sort(array,cmp) implements a heap sort of a list in Berry,
with respect to a comparator.

binary_heap.make_heap(array,cmp) transforms a Berry list into a heap.

binary_heap.remove_heap(array,cmp) removes and returns the first element
of a binary heap and maintains the heap property for the remaining
elements. By repeatedly invoking it, one can obtain the first few
elements of a Berry list in a sorted order, without having to sort
all elements.

The example program can be run as follows:
berry -m modules modules/examples/binary_heap_sort.be

Author: dr-m

modules/binary_heap.be

@@ -0,0 +1,45 @@
+# https://en.wikipedia.org/wiki/Binary_heap
+# similar to C++11 std::make_heap
+
+def heapify(array, cmp, i)
+  while true
+    var m = i, child = 2 * i
+    child += 1
+    if child >= array.size() return end
+    if cmp(array[child], array[m]) m = child end
+    child += 1
+    if child < array.size() && cmp(array[child], array[m]) m = child end
+    if m == i break end
+    var e = array[i]
+    array[i] = array[m]
+    i = m
+    array[i] = e
+  end
+end
+
+var binary_heap = module("binary_heap")
+
+binary_heap.make_heap = def(array, cmp)
+  for i: range(size(array) / 2, 0, -1) heapify(array, cmp, i) end
+end
+
+binary_heap.remove_heap = def(array, cmp)
+  if array.size() == 0
+    return array
+  elif array.size() == 1
+    return array.pop()
+  end
+  var m = array[0]
+  array[0] = array.pop()
+  heapify(array, cmp, 0)
+  return m
+end
+
+binary_heap.sort = def(array, cmp)
+  var heap = array.copy()
+  binary_heap.make_heap(heap, cmp)
+  array.clear()
+  for i: 1..heap.size() array.push(binary_heap.remove_heap(heap, cmp)) end
+end
+
+return binary_heap

modules/examples/binary_heap_sort.be

@@ -0,0 +1,25 @@
+import binary_heap
+
+var pi = [3,14,15,92,65,35,89,79,32,38,46,26,43,38,32,79,50,28,84,19,71,69,39]
+# Display the elements of pi[] in ascending order
+var h = pi.copy()
+var less = / a b -> a < b, sort = binary_heap.sort
+sort(h, less)
+print(h)
+
+# Display the 5 largest elements of pi[]
+var cmp = / a b -> a > b
+var max = []
+binary_heap.make_heap(h, cmp)
+for i: 1..5 max.push(binary_heap.remove_heap(h, cmp)) end
+print(max)
+
+# Display the 7 largest elements of pi[] in ascending order of index
+h = []
+for i: 0..pi.size()-1 h.push(i) end
+cmp = / a b -> pi[a] > pi[b]
+binary_heap.make_heap(h, cmp)
+max = []
+for i: 1..7 max.push(binary_heap.remove_heap(h, cmp)) end
+sort(max, less)
+for i: 0..6 print(f"{max[i]}: {pi[max[i]]}") end