spirv-opt --convert-relaxed-to-half pass introducing bugs in shader

[danginsburg]

I am facing a number of issues attempting to use --convert-relaxed-to-half to convert shaders with RelaxedPrecision into using true float16. Some of them fail in the NVIDIA driver with vkCreateGraphicsPipelines returning VK_ERROR_UNKNOWN, crash in the AMD Windows driver, and assert on RADV. In most cases, I do not get spirv-val errors. Although I was able to find a case that produced a spirv-val error attached in this bug to maybe narrow down the issues.

>spirv-opt --version
SPIRV-Tools v2025.4 v2025.4-0-g7f2d9ee9
>spirv-opt --convert-relaxed-to-half --simplify-instructions --redundancy-elimination --eliminate-dead-code-aggressive relaxed_precision.spv -o half.spv 
>spirv-val relaxed_precision.spv --target-env vulkan1.4

>spirv-val half.spv --target-env vulkan1.4
error: line 388: Result type (OpTypeVector) does not match the type that results from indexing into the composite (OpTypeVector).
  %19019 = OpCompositeExtract %v4half %14911 0

As shown above, you can produce a spirv-val error by running the input shader (relaxed_precision.spv) through spirv-opt --convert-relaxed-to-half --simplify-instructions --redundancy-elimination --eliminate-dead-code-aggressive relaxed_precision.spv -o half.spv and it will produce a shader with:

error: line 388: Result type (OpTypeVector) does not match the type that results from indexing into the composite (OpTypeVector).
  %19019 = OpCompositeExtract %v4half %14911 0

Often, I find it is producing pixel shaders that do not have spirv-val errors, but fail in the driver, such as the other shader pair attached (vr_simple.vfx_vs_34.spv and vr_simple.vfx_ps_34.spv). I unfortunately don't easily have access to the exact inputs that produced the output pixel shader here. Converting those shaders into a foz file with

fossilize-synth --vert vr_simple.vfx_vs_34.spv --frag vr_simple.vfx_ps_34.spv --output vr_simple.foz

and replaying on RADV give an assert:

> fossilize-replay: ../src/amd/compiler/instruction_selection/aco_select_nir.cpp:145: void aco::(anonymous namespace)::visit_tex(isel_context *, nir_tex_instr *): Assertion `instr->src[i].src.ssa->bit_size == (a16 ? 16 : 32)' failed.

relaxed_precision.zip

vr_simple.vfx_ps_34.zip

[spencer-lunarg]

So it seems the issue with the vr_simple.vfx_ps_34.spv is

%7499 = OpImageSampleExplicitLod %v4float %7490 %7497 Lod %5284

where %5284 is a float16 and should not be

will get the spirv-val to catch the Lod operand is of type float16 here

[danginsburg]

So running with your PR @spencer-lunarg I have a trivial reproducer of the bug using spirv-opt built to 2829848.

Given the input shader: (https://godbolt.org/z/vhYhPP3j9)

; SPIR-V
; Version: 1.0
; Generator: Khronos Glslang Reference Front End; 11
; Bound: 24608
; Schema: 0
               OpCapability Shader
               OpCapability SampledCubeArray
          %1 = OpExtInstImport "GLSL.std.450"
               OpMemoryModel Logical GLSL450
               OpEntryPoint Fragment %5663 "main" %4317
               OpExecutionMode %5663 OriginUpperLeft
               OpDecorate %3424 Binding 160
               OpDecorate %3424 DescriptorSet 0
               OpDecorate %3196 Binding 70
               OpDecorate %3196 DescriptorSet 0
               OpDecorate %_struct_985 Block
               OpMemberDecorate %_struct_985 0 Offset 44
               OpDecorate %4930 Binding 0
               OpDecorate %4930 DescriptorSet 1
               OpDecorate %4317 RelaxedPrecision
               OpDecorate %4317 Location 0
               OpDecorate %19593 RelaxedPrecision
               OpDecorate %18219 RelaxedPrecision
               OpDecorate %9798 RelaxedPrecision
               OpDecorate %6796 RelaxedPrecision
       %void = OpTypeVoid
       %1282 = OpTypeFunction %void
      %float = OpTypeFloat 32
    %v4float = OpTypeVector %float 4
        %int = OpTypeInt 32 1
        %216 = OpTypeImage %float Cube 0 1 0 1 Unknown
%_ptr_UniformConstant_216 = OpTypePointer UniformConstant %216
       %3424 = OpVariable %_ptr_UniformConstant_216 UniformConstant
        %508 = OpTypeSampler
%_ptr_UniformConstant_508 = OpTypePointer UniformConstant %508
       %3196 = OpVariable %_ptr_UniformConstant_508 UniformConstant
        %510 = OpTypeSampledImage %216
    %float_0 = OpConstant %float 0
    %float_1 = OpConstant %float 1
       %2004 = OpConstantComposite %v4float %float_0 %float_1 %float_0 %float_0
%_struct_985 = OpTypeStruct %float
%_ptr_Uniform__struct_985 = OpTypePointer Uniform %_struct_985
       %4930 = OpVariable %_ptr_Uniform__struct_985 Uniform
%_ptr_Uniform_float = OpTypePointer Uniform %float
%_ptr_Output_v4float = OpTypePointer Output %v4float
       %4317 = OpVariable %_ptr_Output_v4float Output
       %uint = OpTypeInt 32 0
     %uint_0 = OpConstant %uint 0
       %5663 = OpFunction %void None %1282
      %24607 = OpLabel
      %21229 = OpLoad %216 %3424
      %19523 = OpLoad %508 %3196
      %15746 = OpSampledImage %510 %21229 %19523
      %17415 = OpAccessChain %_ptr_Uniform_float %4930 %uint_0
      %19593 = OpLoad %float %17415
      %18219 = OpConvertFToS %int %19593
       %9798 = OpConvertSToF %float %18219
       %6796 = OpImageSampleExplicitLod %v4float %15746 %2004 Lod %9798
               OpStore %4317 %6796
               OpReturn
               OpFunctionEnd

Running: spirv-opt --convert-relaxed-to-half relaxed_precision.spv -o half.spv will produce:

; SPIR-V
; Version: 1.0
; Generator: Khronos Glslang Reference Front End; 11
; Bound: 24609
; Schema: 0
               OpCapability Shader
               OpCapability SampledCubeArray
               OpCapability Float16
          %1 = OpExtInstImport "GLSL.std.450"
               OpMemoryModel Logical GLSL450
               OpEntryPoint Fragment %5663 "main" %4317
               OpExecutionMode %5663 OriginUpperLeft
               OpDecorate %3424 Binding 160
               OpDecorate %3424 DescriptorSet 0
               OpDecorate %3196 Binding 70
               OpDecorate %3196 DescriptorSet 0
               OpDecorate %_struct_985 Block
               OpMemberDecorate %_struct_985 0 Offset 44
               OpDecorate %4930 Binding 0
               OpDecorate %4930 DescriptorSet 1
               OpDecorate %4317 Location 0
               OpDecorate %18219 RelaxedPrecision
       %void = OpTypeVoid
       %1282 = OpTypeFunction %void
      %float = OpTypeFloat 32
    %v4float = OpTypeVector %float 4
        %int = OpTypeInt 32 1
        %216 = OpTypeImage %float Cube 0 1 0 1 Unknown
%_ptr_UniformConstant_216 = OpTypePointer UniformConstant %216
       %3424 = OpVariable %_ptr_UniformConstant_216 UniformConstant
        %508 = OpTypeSampler
%_ptr_UniformConstant_508 = OpTypePointer UniformConstant %508
       %3196 = OpVariable %_ptr_UniformConstant_508 UniformConstant
        %510 = OpTypeSampledImage %216
    %float_0 = OpConstant %float 0
    %float_1 = OpConstant %float 1
       %2004 = OpConstantComposite %v4float %float_0 %float_1 %float_0 %float_0
%_struct_985 = OpTypeStruct %float
%_ptr_Uniform__struct_985 = OpTypePointer Uniform %_struct_985
       %4930 = OpVariable %_ptr_Uniform__struct_985 Uniform
%_ptr_Uniform_float = OpTypePointer Uniform %float
%_ptr_Output_v4float = OpTypePointer Output %v4float
       %4317 = OpVariable %_ptr_Output_v4float Output
       %uint = OpTypeInt 32 0
     %uint_0 = OpConstant %uint 0
       %half = OpTypeFloat 16
       %5663 = OpFunction %void None %1282
      %24607 = OpLabel
      %21229 = OpLoad %216 %3424
      %19523 = OpLoad %508 %3196
      %15746 = OpSampledImage %510 %21229 %19523
      %17415 = OpAccessChain %_ptr_Uniform_float %4930 %uint_0
      %19593 = OpLoad %float %17415
      %18219 = OpConvertFToS %int %19593
       %9798 = OpConvertSToF %half %18219
       %6796 = OpImageSampleExplicitLod %v4float %15746 %2004 Lod %9798
               OpStore %4317 %6796
               OpReturn
               OpFunctionEnd

....which gives this validation error with your changes:

error: line 51: Expected Image Operand Lod to be a 32-bit float scalar when used with ExplicitLod
  %6796 = OpImageSampleExplicitLod %v4float %15746 %2004 Lod %9798

relaxed_precision.zip